可能很多人都会遇到一种情况，在单位，平时工作使用的笔记本电脑，都是设置固定IP连到局域网，再连到互联网，在某些情况下，可能又需要设置为“自动获取”方式来自动分配IP（当然，现在出差住酒店一般都用无线，就不需要参看本文了），这个时候，切换的时候点来点去很烦人，本文介绍一种用批处理的简单方法，来简化这个操作。

本文介绍的方法基于netsh命令，这是一个windowsXP和win7自带的操作系统命令，功能非常丰富，大家可以自己搜索这个命令的资料，这里只介绍IP地址相关的功能，后面附带批处理的实际脚本文档。

一、设置自动IP和自动DNS

netsh interface ip set address name="本地连接" source=dhcp
netsh interface ip set dns name="本地连接" source=dhcp

二、设置固定IP和固定DNS

netsh interface ip set address name="本地连接" source=static addr=192.168.1.10 mask=255.255.255.0
netsh interface ip set address name="本地连接" gateway=192.168.1.1 gwmetric=0
netsh interface ip set dns name="本地连接" source=static addr=202.96.209.5 register=PRIMARY

可以把这两个命令写成批处理，再双击运行即可！

三、把一个笔记本（已连到互联网）做成手机wifi热点，也使用了netsh命令，示例如下：

netsh wlan set hostednetwork mode=allow ssid=MYSSID key=12345678
netsh wlan start hostednetwork

请务必记住，在win7下运行这个批处理的命令，需要以管理员身份来运行哦！否则会有莫名其妙的小问题出现。

四、以下是批处理命令

@echo off 
title 设置上网环境
echo ★★★★请选择上网环境★★★★
echo ▼IP固定模式————→请按 1
echo ▼IP自动模式————→请按 2 
set /p n=
if /i "%n%" equ "1" goto guding
if /i "%n%" equ "2" goto zidong
: guding
echo ===================================
echo 您选择了IP固定IP模式
echo 请输入以下信息......
echo ===================================
echo   ***     IP地址:    ***
     set /p addr=
echo   ***    网关地址:   ***
     set /p gateway= 
netsh interface ip set address name="本地连接" source=static addr=%addr% mask=255.255.255.0 gateway=%gateway% gwmetric=0 >nul
 echo 正在添加本机主DNS... 
netsh interface ip set dns name="本地连接" source=static addr=%gateway% register=PRIMARY 
goto end 
: zidong
echo ===================================
echo 您选择了IP自动获取模式
echo 正在设置，请稍后......
echo 自动获取IP地址....
echo =================================== 
@echo off 
netsh interface ip set address name="本地连接" source=dhcp 
echo 自动获取DNS服务器.... 
netsh interface ip set dns name="本地连接" source=dhcp 
goto end 
:end 
echo ☆☆☆☆☆☆☆☆本机当前IP配置如下☆☆☆☆☆☆☆☆☆☆☆☆ 
ipconfig 
echo ☆☆☆☆☆☆☆☆设置成功!感谢使用☆☆☆☆☆☆☆☆☆☆☆☆ 
pause>nul

 五、附上几张验证图片

1、运行IP固定模式

2、运行IP自动模式